Clear["Global`*"]
$Line=0;

CFT and Gravity 2018 - Week 3

Exercise 1

Define (Subscript[g, μν]), a scalar product · and rules for contractions

Attributes[CenterDot]={Orderless};
(a_+b_)·c_:=a·c+b·c
a_·(α_ b_):=α (a·b)/;NumberQ[α]
Attributes[g]=Orderless;
dot:=((Expand[#]//. {
z_[μ_] y_[μ_]:>z·y,((z_[μ_])^2):>z·z,g[μ_,ν_]z_[ν_]:>z[μ],g[μ_,α_]g[α_,ν_]:> g[μ,ν] ,((g[μ_,ν_])^2):>d,g[μ_,μ_]:>d})//Simplify)&

Warning: it does not handle mistakes in the repeated indices: see first example below. So please contract indices properly in the following.

x[μ]x[α] y[μ]x[μ]//dot
x[μ]x[α] y[μ]x[α]//dot
x[μ](x[μ]+y[μ])//dot
x[μ](x[ν]+y[ν])g[μ,ν]//dot
g[μ,ν]g[ν,μ]//dot

Define (∂_μ)

der[x_][μ_][expr_] takes three arguments: the point x, the direction μ and the expression to be derived. We use the command SeriesCoefficient that knows already about linearity and Leibnitz rule:

der[x_][μ_][A_]:=(A/.{
x[α_]:> x[α]+ϵ g[μ,α],x·x:> x·x+2ϵ x[μ],x·y_:> x·y+ϵ y[μ]})//SeriesCoefficient[#,{ϵ,0,1}]&

der[x][μ][x·x]
der[x][μ][x·y]
der[x][μ][f[x·y]]

Define the generators of the conformal group at point x:

P[μ_][A_]:=-I der[x][μ][A]
M[μ_,ν_][A_]:=-I (x[μ]der[x][ν][A]-x[ν]der[x][μ][A])
Di[A_]:=-Module[{λ},x[λ]der[x][λ][A]]
Ks[μ_][A_]:=2 I x[μ]Module[{λ},x[λ]der[x][λ][A]]-I x·x der[x][μ][A]

Compute the algebra by applying to a generic function.

We must choose the function to depend on the full vector x[μ] rather than on (x^2), otherwise the rotation generator acts trivially. We do something intermediate and choose a projection onto an arbitrary direction k: x·k

(Di[P[μ][#]]-P[μ][Di[#]]== P[μ][#])&[f[x·k]]//dot
(Di[Ks[μ][#]]-Ks[μ][Di[#]]==-Ks[μ][#])&[f[x·y,x·z]]//dot
(Ks[μ][P[ν][#]]-P[ν][Ks[μ][#]]==2 g[μ,ν]Di[#]-2I M[μ,ν][#])&[f[x·y]]//dot
(M[μ,ν][P[α][#]]-P[α][M[μ,ν][#]]==I(g[μ,α] P[ν][#]-g[ν,α]P[μ][#]))&[f[x·y]]//dot
(M[μ,ν][Ks[α][#]]-Ks[α][M[μ,ν][#]]==I(g[μ,α] Ks[ν][#]-g[ν,α]Ks[μ][#]))&[f[x·y]]//dot
(M[α,β][M[μ,ν][#]]-M[μ,ν][M[α,β][#]]==I(g[α,μ]M[β,ν][#]+g[β,ν]M[α,μ][#]-g[α,ν]M[β,μ][#]-g[β,μ]M[α,ν][#]))&[f[x·y]]//dot

exercise 4

a)

The expression proposed in the exercise is clearly covariant under the Poincaré group, therefore we only need to check the behavior under inversion. Instead of using brute force, let’s follow the hints given in the text.

Check how distances transform under inversions:

(((((x1[μ])/(x1·x1))-((x2[μ])/(x2·x2))))^2)==((((x1[μ]-x2[μ]))^2)/(x1·x1 x2·x2))//dot

Check the transformation properties of (V^μ):

V[μ_]=(((Subscript[x, 1])[μ]-(Subscript[x, 3])[μ])/(dist[1,3]))-(((Subscript[x, 2])[μ]-(Subscript[x, 3])[μ])/(dist[2,3]))

Btw, the Jacobian of the inversion is closely related to the inversion matrix:

Inv[x_][μ_,ν_]:=g[μ,ν]-2 ((x[μ]x[ν])/(x·x))

der[x][μ][((x[ν])/(x·x))]==(1/(x·x)) Inv[x][μ,ν]//Simplify

This checks the transformation rule of (V^μ)

V[μ]/.{(Subscript[x, i_])[μ]->(((Subscript[x, i])[μ])/((Subscript[x, i])·(Subscript[x, i]))),dist[i_,j_]->((dist[i,j])/((Subscript[x, i])·(Subscript[x, i]) (Subscript[x, j])·(Subscript[x, j])))}//Expand
(1/((Subscript[x, 3])·(Subscript[x, 3]))) Inv[(Subscript[x, 3])][ν,μ]%//dot//Expand
(%==V[ν])/.dist[i_,j_]->((Subscript[x, i])-(Subscript[x, j]))·((Subscript[x, i])-(Subscript[x, j]))//Simplify

This takes care of the tensor part in the transformation law of (Subscript[j, μ])
All what is left is to match scaling dimensions.
The inversion is an orthogonal matrix:

Inv[x][μ,ν]Inv[x][ν,ρ]//dot

so it has eigenvalues ±1. This means
|((∂x')/(∂x))|= ((((x^2)))^(-d)) .

Define the prefactors of (V^μ) in the correlator:

pref=((dist[1,2])^(α12)) ((dist[1,3])^(α13)) ((dist[2,3])^(α23));

pref must obey the following relation:
pref = pref’ ((((x1^2)))^(-Δ1)) ((((x2^2)))^(-Δ2)) ((((x3^2)))^(-(Δ3-1)))

pref/.dist[i_,j_]->((dist[i,j])/((Subscript[x, i])·(Subscript[x, i]) (Subscript[x, j])·(Subscript[x, j])))
% ((((Subscript[x, 1])·(Subscript[x, 1])))^(-Δ1)) ((((Subscript[x, 2])·(Subscript[x, 2])))^(-Δ2))((((Subscript[x, 3])·(Subscript[x, 3])))^(-(Δ-1)));
%/pref//PowerExpand
Solve[Cases[%,((((Subscript[x, i_])·(Subscript[x, i_])))^(a_))->a]==0,{α12,α13,α23}]

this coincides with the proposed form of the correlator.

b)

The product (V^μ)(V^ν) clearly respects the tensor transformation rule, and so does (Subscript[g, μν]). On the other hand (Subscript[V, α])(V^α) is invariant. The combination
(Subscript[H, μν])= (Subscript[V, μ]) (Subscript[V, ν])-(1/d)(V^α)(Subscript[V, α])(Subscript[g, μν])
therefore also respects the rule, and the coefficient is fixed by requiring (Subscript[(H^μ), μ])=0.
The only thing to be checked is again the scaling of the prefactor, and the check is almost the same as in the spin 1 case.

Unicity

So far we verified that a certain tensor structure is compatible with the transformation property of the correlator. We can actually argue that there can be only one. 

The argument goes as follows:

1. Use conformal transformations to send (Subscript[O, 1]) to the origin and (Subscript[O, 2]) to infinity. 
2. Now the correlator only depends on ((Subscript[x, 3])^μ), and there is a unique traceless symmetric tensor built out of a single vector.
3. Suppose that there were two tensor structures that become degenerate when (Subscript[x, 1])->0 and (Subscript[x, 2])->∞. This is inconsistent because the conformal transformations are invertible.

d)

Let’s build a function that applies Wick theorem (an overkill for this exercise, but useful in general).
First we implement point splitting for fields evaluated at the same point:

split[a_]:=List@@(a/.((ϕ[b_])^(n_)):> Times@@Table[ϕ[b[i]],{i,1,n}])

Then we define the wick function to take a list of fields.

wick[{}]:=1;
wick[{num_}]:=num/;NumberQ[num]
wick[{a_}]:=0
wick[{num_,a__}]:=num wick[{a}]/;NumberQ[num]
wick[{a_,b_}]:=⟨a b⟩
wick[a_ ]:=Module[{aux=Delete[a,1]},Sum[⟨a[[1]]aux[[j]]⟩wick[Delete[aux,j]],{j,1,Length[aux]}]]

For instance:

wick[{ϕ[(Subscript[x, 1])],ϕ[(Subscript[x, 2])],ϕ[(Subscript[x, 3])],ϕ[(Subscript[x, 4])]}]

We define (Subscript[T, μν]) as the sum of two differential operators which act on fields. 
(∂_μ)ϕ(∂_ν)ϕ is defined via point splitting, while the second piece is a differential operator directly acting on (ϕ^2)

t1[x_,y_][μ_,ν_]=der[x][μ][der[y][ν][#]]&;
t2[x_][μ_,ν_]=((-1)/(4 (d-1)))((d-2) der[x][μ][der[x][ν][#]]+g[μ,ν]der[x][λ][der[x][λ][#]])&;

The correlator is obtained by applying these differential operator to the appropriate scalar correlators:

t1: notice that we need to subtract contractions between ϕ[x] and ϕ[y] since in (Subscript[T, μν]) these fields are normal ordered and evaluated in the same point:

split[ϕ[(Subscript[x, 1])]ϕ[(Subscript[x, 2])]ϕ[(Subscript[x, s])]ϕ[(Subscript[y, s])]];
wick[%]/.⟨ϕ[(Subscript[x, s])] ϕ[(Subscript[y, s])]⟩->0/.⟨ϕ[a_] ϕ[b_]⟩->(norm/((((a-b)·(a-b)))^((d-2)/2)))
t1piece=t1[(Subscript[x, s]),(Subscript[y, s])][μ,ν][%]/.{(Subscript[x, s])->(Subscript[x, 3]),(Subscript[y, s])->(Subscript[x, 3])};

split[ϕ[(Subscript[x, 1])]ϕ[(Subscript[x, 2])]((ϕ[x])^2)]
wick[%]/.⟨ϕ[x[1]] ϕ[x[2]]⟩->0/.{x[1]->(Subscript[x, 3]),x[2]->(Subscript[x, 3])}/.⟨ϕ[a_] ϕ[b_]⟩->(norm/((((a-b)·(a-b)))^((d-2)/2)))
t2piece=t2[(Subscript[x, 3])][μ,ν][%]//dot;

tcorr=t1piece+t2piece;

Now we compare this result with the prediction from conformal invariance.

(V[μ]V[ν]-(1/d)V[α]V[α]g[μ,ν]//dot);
(((Subscript[c, 12T])%)/(((dist[1,2])^((Δ1+Δ2-Δ+2)/2))((dist[1,3])^((Δ1+Δ-Δ2-2)/2))((dist[2,3])^((Δ2+Δ-Δ1-2)/2))))/.dist[i_,j_]->((Subscript[x, i])-(Subscript[x, j]))·((Subscript[x, i])-(Subscript[x, j]));
zero=%-tcorr//Expand//Collect[#,{g[μ,ν],(Subscript[x, 1])[μ](Subscript[x, 1])[ν],(Subscript[x, 2])[μ](Subscript[x, 2])[ν],(Subscript[x, 3])[μ](Subscript[x, 3])[ν],(Subscript[x, 1])[μ](Subscript[x, 2])[ν],(Subscript[x, 1])[μ](Subscript[x, 3])[ν],(Subscript[x, 2])[μ](Subscript[x, 3])[ν],(Subscript[x, 1])[ν](Subscript[x, 1])[μ],(Subscript[x, 2])[ν](Subscript[x, 2])[μ],(Subscript[x, 3])[ν](Subscript[x, 3])[μ],(Subscript[x, 1])[ν](Subscript[x, 2])[μ],(Subscript[x, 1])[ν](Subscript[x, 3])[μ],(Subscript[x, 2])[ν](Subscript[x, 3])[μ]},f[#]&]&//Cases[#,f[a_]->a,∞]&

What we did here is to subtract the expected form to the computed one: so zero should be zero.
Each tensor structure gives an independent equation (at least in principle), so we built a list of the coefficients of all the tensor structures.

The result is quite complicated, so we can introduce a bit of notation to simplify it:

zerosimp=zero/.(Subscript[x, i_])·(Subscript[x, j_])->((-1)/2)(dist[i,j]-(Subscript[x, i])·(Subscript[x, i])-(Subscript[x, j])·(Subscript[x, j]))/.dist[i_,i_]->0//Simplify

Still long, but much better: in particular the first equation looks very promising. Let’s isolate it and see how many parameters it determines:

zerosimp[[1,-1]]//Expand//Simplify
%//List@@#&//((#[[1]])/(#[[2]]))&//Cases[#,((dist[i_,j_])^(α_))->α==0]&
dimensions=Solve[%,{Δ1,Δ2,Δ}][[1]]
%%%/.dimensions//Simplify
c12t=Solve[%==0,(Subscript[c, 12T])][[1]]

So one equation already determines both the scaling dimensions and the coefficient of the three point function. All the others better be automatically satisfied:

zero/.dimensions/.c12t//Simplify